***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 11, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJC7439-AU   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -1.7		 kp = 9.0e-1		)
.model  dds   d(
+   is = 1.645e-12	  n = 1.085		   rs = 4.231e-2
+   eg = 1.002	       trs1 = 2.145e-3)
.model  dbody d(
+   is = 1.645e-12	  n = 1.085		   rs = 4.231e-2
+ trs1 = 2.145e-3
+  cjo = 1.406e-11	  m = 1.156e-1		   vj = 9.990e-0
+   bv = 66		ibv = 250e-6		 tbv1 = 5.338e-4		tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 1.068e-11	  m = 3.983e-1		   vj = 7.551e-1)
.param
+  cgs = 6.520e-11	cgd = 1.100e-11
+   rd = 2.400e-0	 ra = 1.000e-1		  trd = 6.041e-3
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (1.50 , 1.50 ),
+ (2.00 , 1.95 ),
+ (2.50 , 2.35 ),
+ (2.80 , 2.60 ),
+ (3.00 , 2.75 ),
+ (3.50 , 3.30 ),
+ (4.00 , 3.95 ),
+ (4.50 , 4.70 ),
+ (5.00 , 5.50 ),
+ (6.00 , 7.50 ),
+ (8.00 , 10.0 ),
+ (10.0 , 12.0 ),
+ (20.0 , 21.0 ),
+ (22.0 , 21.0 ))
egt	  1  2t   value = {1.807e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
